将 Dancer 插件移植到 Dancer2

2020年1月10日 by Christopher White

在我的 Dancer2 网络应用程序中，我想知道哪些请求来自智能手机。为此有一个插件——但只适用于较老的 Dancer (v1) 框架。我不是专家，但即使是我也很容易将 Dancer 插件，Dancer::Plugin::MobileDevice，移植到 Dancer2！在这篇文章中，我们将探索 Dancer2 及其处理插件的方式。我们将深入框架的工作，并检查我为了将插件从 Dancer 移植到 Dancer2 而做出的主要更改。到文章结束时，你将准备好大显身手，并且你将拥有一个便携式参考，以便在移植插件时使用。

Dancer2 网络框架

Dancer2 应用程序在 Web 服务器上运行并处理来自浏览器的请求。应用程序的 Perl 代码使用 Dancer2 的领域特定语言（DSL）中的关键字来访问有关请求的信息。

试试这个：安装 Task::Dancer2。然后，将其保存为 app.psgi

use Dancer2;
get '/' => sub {
    return 'Hello, ' . (query_parameters->{name} || 'world') . '!';
};
to_app;

并运行 plackup。

在浏览器中输入 URL http://localhost:5000，你将看到“Hello, world!”，或者访问 http://localhost:5000/?name=genius 以看到“Hello, genius!”。这里的“genius”来自 query_parameters，这是一个 DSL 关键字，它返回 URL 中 ? 之后的价值。你可以使用这些值来构建对请求的响应。

Dancer 和 Dancer2 插件

Dancer 和 Dancer2 插件为插件的用户定义了新的 DSL 关键字。它们还安装了“钩子”，这些是 Dancer 处理请求时运行的子例程。钩子收集 DSL 关键字可以访问的信息。

例如，Dancer::Plugin::MobileDevice 中的钩子检测请求是否来自移动设备。该插件定义了 is_mobile_device DSL 关键字，以便你的代码可以相应地作出反应。为了移植插件，我更改了关键字、钩子和测试套件的代码。

移植关键字

Dancer 插件使用 Dancer DSL 和特定于插件的 DSL 来定义 DSL 关键字。在 Dancer (v1) 中，使用 register 插件-DSL 函数创建 is_mobile_device 关键字（代码示例简化，以关注移植）

register 'is_mobile_device' => sub {
    return request->user_agent =~ /$regex/ || 0;
};
register_plugin;

Dancer2 插件是 Moo 对象，新的 DSL 关键字是这些对象上的成员函数。因此，我将 is_mobile_device() 更改为成员函数

sub is_mobile_device {
    my $self = shift;       # get the plugin’s object instance
    return ($self->dsl->request->user_agent =~ /$regex/) || 0 ;
}
plugin_keywords qw(is_mobile_device);   # replaces register_plugin()

在函数体中，Dancer 插件直接访问 DSL 关键字 request。Dancer2 插件则通过 $self->dsl->request 访问请求。

移植钩子

Dancer 插件使用 DSL 关键字 hook 添加钩子。例如，此 before_template 钩子在模板中使 is_mobile_device 可用

hook before_template => sub {
    my $tokens = shift;
    $tokens->{'is_mobile_device'} = is_mobile_device();
};

Dancer2 处理钩子的方式非常不同。插件实例创建时，将调用插件的 Moo 构造函数 BUILD。在 BUILD 中，插件注册钩子。我添加了 BUILD 并调用 $self->dsl->hook 来添加钩子

sub BUILD {
    my $self = shift;
    $self->dsl->hook( before_template_render => sub {
        my $tokens = shift;
        $tokens->{is_mobile_device} = $plugin->is_mobile_device;
    });
}

如果你的钩子函数太长而无法移动到 BUILD 中，你可以将其保留在原地，并使用 $self->dsl->hook( hook_name => \&sub_name );。

移植测试

Dancer::Plugin::MobileDevice 有一个完整的测试套件。这些测试对开发者来说非常有用，因为它们允许你查看 Dancer2 移植是否与 Dancer 原始版本行为相同。也就是说，在使用这些测试来测试你的移植插件之前，你必须先移植这些测试！我们将先看看 Dancer 的方法，然后我会向你展示 Dancer2 的更改。

舞者测试定义了一个使用插件的简单Web应用。它们使用Dancer::Test中的辅助器来测试该应用。例如（简化自t/01-is-mobile-device.t）：

{   # The simple application
    use Dancer;
    use Dancer::Plugin::MobileDevice;
    get '/' => sub { return is_mobile_device; };
}

use Dancer::Test;

$ENV{HTTP_USER_AGENT} = 'iPhone';
my $response = dancer_response GET => '/';  # dancer_response() is from Dancer::Test
is( $response->{content}, 1 );

另一方面，Dancer2使用Plack生态系统进行测试，而不是它自己的辅助器。为了在该生态系统中工作，我根据Dancer2手册的“测试”部分对上述测试进行了修改。

use Plack::Test;                        # Additional testing modules
use HTTP::Request::Common;
{
    package TestApp;     # Still a simple application, but now with a name
    use Dancer2;
    use Dancer2::Plugin::MobileDevice;

    get '/' => sub { return is_mobile_device; };
}

my $dut = Plack::Test->create(TestApp->to_app);     # a fake Web server
my $response = $dut->request(GET '/', 'User-Agent' => 'iPhone');
is( $response->content, 1 );